ASP数据库操作类“MC.DBOC”

代码名称：MC.Database Operation Class
名称简写：MC.DBOC
代码语言：ASP（VBScript）

2007-6-25更新
1、ACCESS数据库连接代码格式
2、指针函数使用0、1来代替真假型

code:

---

<%
'请使用此类的朋友不要随便更改类代码。
'除非使用不当，否则不会对您的使用造成任何损失及出现官方版权信息，请放心使用。
Class DataBase
    '类变量
    Private clsName, clsVersion
    '属性，设置数据库路径及错误文字字符串
    Public OpenMode
    Public ErrorWord
    Public DBPath
    Public ServerIP, ServerUID, ServerPWD, ServerName
    Public Conn, RS

    Private Sub class_initialize()
        clsName = "MC.DBOC"
        clsVersion = "2.2.0"
        OpenMode = 0
        ErrorWord = ""
        DBPath = ""
        ServerIP = ""
        ServerUID = ""
        ServerPWD = ""
        ServerName = ""
    End Sub

    Private Sub class_terminate()
    End Sub

    '方法，打开数据库连接、全局变量“Conn”可用、模式0为ACCESS；模式1为MS SQL
    Public Sub OpenDB()
        Set Conn = Server.CreateObject("Adodb.Connection")
        On Error Resume Next
        Select Case CLng(OpenMode)
        Case 0
            Conn.Open("Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(DBPath))
        Case 1
            Conn.Open("DRIVER=SQL Server; Server=" & ServerIP & "; UID=" & ServerUID & "; PWD=" & ServerPWD & "; Database=" & ServerName & ";")
        End Select
        If Err Then
            Err.Clear()
            Call CloseDB()
            Response.Clear()
            Response.Write("[" & clsName & "]&nbsp;" & ErrorWord)
            Response.End()
        End If
    End Sub

    '方法，关闭数据库连接、全局变量“Conn”不可用
    Public Sub CloseDB()
        If IsObject(Conn) Then
            Conn.Close()
            Set Conn = Nothing
        End If
    End Sub

    '方法，打开记录集、全局变量“RS”可用，参数iRead为0时只读，否则可写
    Public Sub OpenRS(sSQL, iRead)
        Set RS = Server.CreateObject("ADODB.Recordset")
        Select Case CLng(iRead)
        Case 0
            RS.Open(sSQL), Conn, 1, 1
        Case Else
            RS.Open(sSQL), Conn, 1, 3
        End Select
    End Sub

    '方法，关闭记录集、全局变量“RS”不可用
    Public Sub CloseRS()
        If IsObject(RS) Then
            RS.Close()
            Set RS = Nothing
        End If
    End Sub
End Class
%>

---